#AutoGMnaviC.mscr v. 2008/3/21 ################
#GoogleMaps.exeとnaviClip.exeを使って現在位置近隣の地図を表示するMortScript
#
#W-ZERO3 WS003SHで動作確認
#for MortScript 4.1 Release & Google Maps Mobile v2.0.0.11
#
#by モバイル板MortScriptスレの１
#ref. to http://pc11.2ch.net/test/read.cgi/mobile/1200917379/l50
#
#【更新】
# ・Google Maps Mobile v2.0.0.11 をコマンドラインオプションで起動するようにしました。
# 　参考：SYWAREの記事 
# （http://www.syware.com/support/customer_support/tip_of_the_month/tip_0709.php）
#
#・地図が「いちいち小縮尺で表示」されなくなったので、自動ズームインをやめました。
#・「接続中」ポップアップメッセージが関係なくなったので、メッセージ通知の一時無効化をやめました。
#・GoogleMaps.exeが既に起動中の場合、挙動がおかしい場合があるので、対処してあります。
#
#
# ＜使い方＞
# Google Maps Mobile v2.0.0.11インストール直後に一回だけGoogle Maps Mobileを手動で起動して
# 使用条件同意＆スタートアップ画面OKしてから使用して下さい。
#
#・以下の作業を自動化します。
#　
#　→ naviClipを起動させる
#　→ GoogleMapsを立ち上げる
#　→座標マーカーのポップアップメッセージを消す
#
#＜別途必要なファイル＞ 
#・GoogleMaps.exe v2.0.0.11（日本語・英語どちらの版でも使えます）
#・naviClip.exe
#  ( http://w-zero3.org/uploader/src/up0344.zip )
#  
#
#保存ディレクトリが異なる場合は、適宜書き換えて下さい。
#
#####################################

Gm = "\Program Files\GoogleMaps\GoogleMaps.exe"
Nv = "\Program Files\naviClip.exe"

msec = 200
title = "AutoGMnaviClip"

ShowWaitCursor

#SetWSIM.exeを使っている人は、以下のブロックを有効にして下さい。#########
# 
# SetWSIM = "\Program Files\SetWSIM.exe"
# x = RegRead( "HKCU", "Software\Sharp\ShPhoneLib", "RFStrength" )
# If ( x = 0 || x = 7 )
#  RunWait( SetWSIM, "/on" )
#  i = 0
#  While( RegRead( "HKCU", "Software\Sharp\ShPhoneLib", "RFStrength" ) < 2 && i < 50 )
#   Sleep( msec )
#   i = i + 1
#  EndWhile
#  If ( i >= 50 )
#   HideWaitCursor
#   Message( "Wave strength is too weak!", "Error! - " & title )
#   Exit
#  EndIf
# EndIf
# 
######ここまで#################################
clipSave = ClipText()
SetClipText( "" )
#naviClipを起動させる
RunWait( Nv )

i = 0
While( ClipText() eq "" && i < 50 )
 Sleep( msec )
 i = i + 1
EndWhile

If ( i >= 50 )
 SetClipText( clipSave )
 HideWaitCursor
 Message( "Couldn't get location data!", "Error! - " & title )
 Exit
EndIf
HideWaitCursor

loc_str = ClipText()
SetClipText( clipSave )
loc_array = Split( loc_str, " " ) 

If( loc_array[1] eq "S" )
 loc_array[1] = "-"
Else
 loc_array[1] = ""
EndIf
If( loc_array[3] eq "W" )
 loc_array[3] = "-"
Else
 loc_array[3] = ""
EndIf

loc_str = loc_array[1] & loc_array[2] & "," & loc_array[3] & loc_array[4]

#Google Mapsを立ち上げる
Run( Gm, "-URL ""?action=locn&a=@latlon:" & loc_str & """" )
Sleep( msec )

i = 0
While ( WndExists( "Google" ) = 0 && i < 100 )
 Sleep( msec )
 i = i + 1
EndWhile
If ( i >= 100 )
 Message( "Couldn't launch Google Maps Mobile!", "Error! - " & title )
 Exit
EndIf

i = 0
While ( WndActive( "Google" ) = 0 && i < 100 )
 Show( "Google" )
 Sleep( msec )
 i = i + 1
EndWhile
If ( i >= 100 )
 Message( "Couldn't activate Google Maps Mobile!", "Error! - " & title )
 Exit
EndIf

win = ActiveWindow()
SendKeys( win, " " )

# インターネット接続が完了するまで待つ
i = 0
While( InternetConnected( "http://google.com") < 1 && i < 50 )
 Sleep( msec )
 i = i + 1
EndWhile

Sleep( 2000 )

#座標マーカーのポップアップメッセージを消す
MouseClick( win, 100, 100 )

#End of script####################